Difference between revisions of "CLASS"

Revision as of 14:38, 28 May 2009

Class

Objects

Purpose

Create a user-defined class

Syntax

CLASS <class name>

[OF <base class> [, …]]

[PUBLIC | PRIVATE]

[DYNAMIC]

[NOTIFY]

[PROPAGATE]

ENDCLASS

See Also

ADDPROPERTY(), CLASS - Methods, CLASS - Parameters, CLASS - Properties, CLASS - Scoping, CREATEOBJECT(), DEFINE CLASS, DISPLAY CLASSES, DODEFAULT(), LIST CLASSES, METHOD, NEWOBJECT(), REMOVEPROPERTY()

Description

The Class construct is a fundamental part of the object-oriented programming language (OOPS) which is part of the Recital/4GL. The OOPS language supports encapsulation, inheritance (single and multiple), polymorphism, complex member scoping, property notification, and method propagation.

Fundamental to object-oriented programming is the concept of Objects and classes. An object is a self-contained unit of data and functions that manipulate that data. A class is a specification of an object. A class contains memory variable specifications known as properties and functions that perform actions on the object known as methods. An object is an instance of a class.

The NEW operator is used to define a new object based on a class. The class name must be postfixed with parentheses when the new operator is used. The syntax is therefore as follows:

<object> = NEW <class>()

e.g. myobject = new myclass()

The CLASS...ENDCLASS construct is used to create a user-defined class. The beginning of a class is specified with CLASS <class name>, where <class name> can be any valid name up to 32 characters. The ENDCLASS command is used to complete the class construct. The CLASS...ENDCLASS construct is built using the commands describe in this section. Any Recital/4GL command can be used in building methods in the class, however these commands cannot be used outside the method definition inside a CLASS...ENDCLASS construct.

OF <base-name> [, ...]

A key feature of the object-oriented code is reusability through a mechanism called inheritance, that is, one class can inherit the members and their implementation from another class. Building new classes out of existing classes allows for the reusing of proven classes and the incorporation of system classes into user defined classes. Inheritance enables developers to build a hierarchy of descending objects. The inheriting class is called a derived class, and the class from which the derived class inherits is called a base class. The OF clause is used to inherit the <base name>. You can inherit multiple classes by specifying a class name comma separated list.

PUBLIC | PRIVATE

A user-defined class by default is defined as PRIVATE, which means that it will be visible only at the level where the class is instantiated. If the PUBLIC clause is specified, then when the class is instantiated, it will be visible at all levels until it is RELEASED from memory.

DYNAMIC

The DYNAMIC keyword provides the ability to add new properties to objects at runtime.

NOTIFY

The Recital/4GL supports what is known as Property notification. If you specify the NOTIFY clause all properties defined will have notify set. Property notification is an essential element in the real-time interaction with system objects. When a property that has been defined with the NOTIFY clause is read, and the class contains a method called GETPROPERTY, that method is called. The property name is passed to the GETPROPERTY method as a parameter.

PROPAGATE

Any methods which are called, which have the PROPAGATE attribute set, cause a cascading execution effect down through the class hierarchy. After the method is executed, a search is made in all of the sub-objects (if any) that are defined as properties within the current object. If a method with the same name is found and that method has the NOTIFY attribute specified, then that method is called.

The CONSTRUCTOR and the DESTRUCTOR methods always act as if sub-objects have the PROPAGATE and the NOTIFY attributes set. This allows any properties that have been specified as sub-objects to operate correctly when an object is created with the NEW operator.

All classes have an inbuilt ADDPROPERTY 'factory method'. This can be used as an alternative to the ADDPROPERTY() function to add properties to an object at runtime.

Example

class NullData dynamic
    property mCHARACTER
    property mNUMERIC
endclass
 
oNULLDATA = new NullData() 
oNULLDATA.mCHARACTER = ""
oNULLDATA.mNUMERIC = 0 
oNULLDATA.mDATE = {  /  /    }
oNULLDATA.mLOGICAL = .f.
 
// Example of Property Notification using the NOTIFY keyword
class CharWin
    public notify:
        property lVISIBLE as logical
        property nROW, nCOL, nENDROW, nENDCOL
    public:
        property cWINDOW
        property cCOLOR
 
        method Constructor 
            parameters cWINDOW, cCOLOR, nROW, nCOL, nENDROW, nENDCOL
            define window &cWINDOW ;
                from nROW, nCOL to nENDROW,nENDCOL ;
                color &cCOLOR panel float grow
            this.cWINDOW = cWINDOW
            this.cCOLOR  = cCOLOR
            this.nROW    = nROW
            this.nCOL    = nCOL
            this.nENDROW = nENDROW
            this.nENDCOL = nENDCOL
        return  && Constructor
 
        method SetProperty
            parameter cNAME
            if lower(cNAME) = "lvisible"
                if this.lVISIBLE
                    activate window &(this.cWINDOW)
                else
                    hide window &(this.cWINDOW)
                endif
            endif
        return  && SetProperty
endclass
 
clear screen
oMYWIN = new CharWin("mywin", "w/r",2,20,15,60)
dialog box "Calling a NOTIFY property"
oMYWIN.lVISIBLE = .t.
?
? "    Welcome to the world of Objects"
?
 
// Example of Constructor & Destructor
class OpenTable
    property cALIAS
    property nRECNUM
 
    method Constructor
        parameters cTABLENAME, cTAGNAME
        local cTMPALIAS
        cTMPALIAS = basename(cTABLENAME)
        cTMPALIAS = iif(at('.',cTMPALIAS) = 0, cTMPALIAS, left(cTMPALIAS,at('.',cTMPALIAS) - 1))
        if select(cTMPALIAS) = 0 
            use &(cTABLENAME + iif(empty(cTAGNAME), '', " order " + cTAGNAME)) in workarea()
        else
            select select(cTABLENAME)
            set order tag &cTAGNAME
        endif
        this.cALIAS = alias()
        this.nRECNUM = recno()
    return  && Constructor
 
    method Destructor
       close &(this.cALIAS)
    return  && Destructor
endclass
 
set exclusive off
oCOMPANY = new OpenTable("/usr/recital/unixdeveloper/demo/state.rdb", "state")
? oCOMPANY.cALIAS 
? oCOMPANY.nRECNUM
 
// Example of dynamically adding properties using the ADDPROPERTY method
class Box 
endclass 
 
oDIALOG = new Box()
oDIALOG.AddProperty("myprop", "hello world") 
dialog box oDIALOG.myprop
release oDIALOG

Products

Recital Database Server, Recital Mirage Server, Recital Terminal Developer